Add files via upload

config/cava/shaders/bar_spectrum.frag

@@ -0,0 +1,79 @@
+#version 330
+
+in vec2 fragCoord;
+out vec4 fragColor;
+
+// bar values. defaults to left channels first (low to high), then right (high to low).
+uniform float bars[512];
+
+uniform int bars_count;    // number of bars (left + right) (configurable)
+uniform int bar_width;    // bar width (configurable), not used here
+uniform int bar_spacing;    // space bewteen bars (configurable)
+
+uniform vec3 u_resolution; // window resolution
+
+//colors, configurable in cava config file (r,g,b) (0.0 - 1.0)
+uniform vec3 bg_color; // background color
+uniform vec3 fg_color; // foreground color
+
+uniform int gradient_count;
+uniform vec3 gradient_colors[8]; // gradient colors
+
+vec3 normalize_C(float y,vec3 col_1, vec3 col_2, float y_min, float y_max)
+{
+    //create color based on fraction of this color and next color
+    float yr = (y - y_min) / (y_max - y_min);
+    return col_1 * (1.0 - yr) + col_2 * yr;
+}
+
+void main()
+{
+    // find which bar to use based on where we are on the x axis
+    float x = u_resolution.x * fragCoord.x;
+    int bar = int(bars_count * fragCoord.x);
+
+    //calculate a bar size
+    float bar_size = u_resolution.x / bars_count;
+
+    //the y coordinate and bar values are the same
+    float y =  bars[bar];
+
+    // make sure there is a thin line at bottom
+    if (y * u_resolution.y < 1.0)
+    {
+      y = 1.0 / u_resolution.y;
+    }
+
+    //draw the bar up to current height
+    if (y > fragCoord.y)
+    {
+        //make some space between bars basen on settings
+        if (x > (bar + 1) * (bar_size) - bar_spacing)
+        {
+            fragColor = vec4(bg_color,1.0);
+        }
+        else
+        {
+            if (gradient_count == 0)
+            {
+                fragColor = vec4(fg_color,1.0);
+            }
+            else
+            {
+                //find which color in the configured gradient we are at
+                int color = int((gradient_count - 1) * fragCoord.y);
+
+                //find where on y this and next color is supposed to be
+                float y_min = color / (gradient_count - 1.0);
+                float y_max = (color + 1.0) / (gradient_count - 1.0);
+
+                //make color
+                fragColor = vec4(normalize_C(fragCoord.y, gradient_colors[color], gradient_colors[color + 1], y_min, y_max), 1.0);
+            }
+        }
+    }
+    else
+    {
+        fragColor = vec4(bg_color,1.0);
+    }
+}

config/cava/shaders/eye_of_phi.frag

@@ -0,0 +1,117 @@
+#version 330
+
+// this shader was stolen from shadertoy user ChunderFPV
+
+#define SCALE 8.0
+#define PI radians(180.0)
+#define TAU (PI * 2.0)
+#define CS(a) vec2(cos(a), sin(a))
+#define PT(u, r) smoothstep(0.0, r, r - length(u))
+
+in vec2 fragCoord;
+out vec4 fragColor;
+
+uniform float bars[512];
+
+uniform int bars_count;    // number of bars (left + right) (configurable)
+uniform float shader_time; // shader execution time s
+uniform int bar_width;     // bar width (configurable), not used here
+uniform int bar_spacing;   // space bewteen bars (configurable)
+
+uniform vec3 u_resolution; // window resolution
+
+// colors, configurable in cava config file (r,g,b) (0.0 - 1.0)
+uniform vec3 bg_color; // background color
+uniform vec3 fg_color; // foreground color
+
+uniform int gradient_count;
+uniform vec3 gradient_colors[8]; // gradient colors
+
+// gradient map ( color, equation, time, width, shadow, reciprocal )
+vec3 gm(vec3 c, float n, float t, float w, float d, bool i) {
+  float g = min(abs(n), 1.0 / abs(n));
+  float s = abs(sin(n * PI - t));
+  if (i)
+    s = min(s, abs(sin(PI / n + t)));
+  return (1.0 - pow(abs(s), w)) * c * pow(g, d) * 6.0;
+}
+
+// denominator spiral, use 1/n for numerator
+// ( screen xy, spiral exponent, decimal, line width, hardness, rotation )
+float ds(vec2 u, float e, float n, float w, float h, float ro) {
+  float ur = length(u);          // unit radius
+  float sr = pow(ur, e);         // spiral radius
+  float a = round(sr) * n * TAU; // arc
+  vec2 xy = CS(a + ro) * ur;     // xy coords
+  float l = PT(u - xy, w);       // line
+  float s = mod(sr + 0.5, 1.0);  // gradient smooth
+  s = min(s, 1.0 - s);           // darken filter
+  return l * s * h;
+}
+
+void main() {
+  float t = shader_time / PI * 2.0;
+  vec4 m = vec4(0, 0, 0, 0);                 // iMouse;
+  m.xy = m.xy * 2.0 / u_resolution.xy - 1.0; // ±1x, ±1y
+  if (m.z > 0.0)
+    t += m.y * SCALE; // move time with mouse y
+  float z = (m.z > 0.0) ? pow(1.0 - abs(m.y), sign(m.y)) : 1.0; // zoom (+)
+  float e = (m.z > 0.0) ? pow(1.0 - abs(m.x), -sign(m.x))
+                        : 1.0;                   // screen exponent (+)
+  float se = (m.z > 0.0) ? e * -sign(m.y) : 1.0; // spiral exponent
+  vec3 bg = vec3(0);                             // black background
+
+  float aa = 3.0; // anti-aliasing
+
+  for (float j = 0.0; j < aa; j++)
+    for (float k = 0.0; k < aa; k++) {
+      vec3 c = vec3(0);
+      vec2 o = vec2(j, k) / aa;
+      vec2 uv = (fragCoord * u_resolution.xy - 0.5 * u_resolution.xy + o) /
+                u_resolution.y * SCALE * z; // apply cartesian, scale and zoom
+      if (m.z > 0.0)
+        uv =
+            exp(log(abs(uv)) * e) * sign(uv); // warp screen space with exponent
+
+      float px = length(fwidth(uv)); // pixel width
+      float x = uv.x;                // every pixel on x
+      float y = uv.y;                // every pixel on y
+      float l = length(uv);          // hypot of xy: sqrt(x*x+y*y)
+
+      float mc = (x * x + y * y - 1.0) / y;  // metallic circle at xy
+      float g = min(abs(mc), 1.0 / abs(mc)); // gradient
+      vec3 gold = vec3(1.0, 0.6, 0.0) * g * l;
+      vec3 blue = vec3(0.3, 0.5, 0.9) * (1.0 - g);
+      vec3 rgb = max(gold, blue);
+
+      float w = 0.1;                                      // line width
+      float d = 0.4;                                      // shadow depth
+      c = max(c, gm(rgb, mc, -t, w * bars[0], d, false)); // metallic
+      c = max(c, gm(rgb, abs(y / x) * sign(y), -t, w * bars[1], d,
+                    false)); // tangent
+      c = max(c, gm(rgb, (x * x) / (y * y) * sign(y), -t, w * bars[2], d,
+                    false)); // sqrt cotangent
+      c = max(c, gm(rgb, (x * x) + (y * y), t, w * bars[3], d,
+                    true)); // sqrt circles
+
+      c += rgb * ds(uv, se, t / TAU, px * 2.0 * bars[4], 2.0, 0.0); // spiral 1a
+      c += rgb * ds(uv, se, t / TAU, px * 2.0 * bars[5], 2.0, PI);  // spiral 1b
+      c +=
+          rgb * ds(uv, -se, t / TAU, px * 2.0 * bars[6], 2.0, 0.0); // spiral 2a
+      c += rgb * ds(uv, -se, t / TAU, px * 2.0 * bars[7], 2.0, PI); // spiral 2b
+      c = max(c, 0.0); // clear negative color
+
+      c += pow(max(1.0 - l, 0.0), 3.0 / z); // center glow
+
+      if (m.z > 0.0) // display grid on click
+      {
+        vec2 xyg = abs(fract(uv + 0.5) - 0.5) / px; // xy grid
+        c.gb += 0.2 * (1.0 - min(min(xyg.x, xyg.y), 1.0));
+      }
+      bg += c;
+    }
+  bg /= aa * aa;
+  bg *= sqrt(bg) * 1.5;
+
+  fragColor = vec4(bg, 1.0);
+}

config/cava/shaders/northern_lights.frag

@@ -0,0 +1,34 @@
+#version 330
+
+in vec2 fragCoord;
+out vec4 fragColor;
+
+// bar values. defaults to left channels first (low to high), then right (high to low).
+uniform float bars[512];
+
+uniform int bars_count;    // number of bars (left + right) (configurable)
+
+uniform vec3 u_resolution; // window resolution, not used here
+
+//colors, configurable in cava config file
+uniform vec3 bg_color; // background color(r,g,b) (0.0 - 1.0), not used here
+uniform vec3 fg_color; // foreground color, not used here
+
+void main()
+{
+    // find which bar to use based on where we are on the x axis
+    int bar = int(bars_count * fragCoord.x);
+
+    float bar_y = 1.0 - abs((fragCoord.y - 0.5)) * 2.0;
+    float y = (bars[bar]) * bar_y;
+
+    float bar_x = (fragCoord.x - float(bar) / float(bars_count)) * bars_count;
+    float bar_r = 1.0 - abs((bar_x - 0.5)) * 2;
+
+    bar_r = bar_r * bar_r * 2;
+
+    // set color
+    fragColor.r = fg_color.x * y * bar_r;
+    fragColor.g = fg_color.y * y * bar_r;
+    fragColor.b = fg_color.z * y * bar_r;
+}

config/cava/shaders/pass_through.vert

@@ -0,0 +1,14 @@
+#version 330
+
+
+// Input vertex data, different for all executions of this shader.
+layout(location = 0) in vec3 vertexPosition_modelspace;
+
+// Output data ; will be interpolated for each fragment.
+out vec2 fragCoord;
+
+void main()
+{
+    gl_Position =  vec4(vertexPosition_modelspace,1);
+    fragCoord  = (vertexPosition_modelspace.xy+vec2(1,1))/2.0;
+}

config/cava/shaders/spectrogram.frag

@@ -0,0 +1,53 @@
+#version 330
+
+in vec2 fragCoord;
+out vec4 fragColor;
+
+// bar values. defaults to left channels first (low to high), then right (high
+// to low).
+uniform float bars[512];
+
+uniform int bars_count;  // number of bars (left + right) (configurable)
+uniform int bar_width;   // bar width (configurable), not used here
+uniform int bar_spacing; // space bewteen bars (configurable)
+
+uniform vec3 u_resolution; // window resolution
+
+// colors, configurable in cava config file (r,g,b) (0.0 - 1.0)
+uniform vec3 bg_color; // background color
+uniform vec3 fg_color; // foreground color
+
+uniform int gradient_count;
+uniform vec3 gradient_colors[8]; // gradient colors
+
+uniform sampler2D inputTexture; // Texture from the first render pass
+
+vec3 normalize_C(float y, vec3 col_1, vec3 col_2, float y_min, float y_max) {
+  // create color based on fraction of this color and next color
+  float yr = (y - y_min) / (y_max - y_min);
+  return col_1 * (1.0 - yr) + col_2 * yr;
+}
+
+void main() {
+  // find which bar to use based on where we are on the y axis
+  int bar = int(bars_count * fragCoord.y);
+  float y = bars[bar];
+  float band_size = 1.0 / float(bars_count);
+  float current_band_min = bar * band_size;
+  float current_band_max = (bar + 1) * band_size;
+
+  int hist_length = 512;
+  float win_size = 1.0 / hist_length;
+
+  if (fragCoord.x > 1.0 - win_size) {
+
+    if (fragCoord.y > current_band_min && fragCoord.y < current_band_max) {
+
+      fragColor = vec4(fg_color * y, 1.0);
+    }
+  } else {
+    vec2 offsetCoord = fragCoord;
+    offsetCoord.x += float(win_size);
+    fragColor = texture(inputTexture, offsetCoord);
+  }
+}

config/cava/shaders/winamp_line_style_spectrum.frag

@@ -0,0 +1,112 @@
+#version 330
+
+// Emulate the "line style" spectrum analyzer from Winamp 2.
+// Try this config for a demonstration:
+
+/*
+[general]
+bar_width = 2
+bar_spacing = 0
+higher_cutoff_freq = 22000
+
+[output]
+method = sdl_glsl
+channels = mono
+fragment_shader = winamp_line_style_spectrum.frag
+
+[color]
+background = '#000000'
+gradient = 1
+gradient_color_1 = '#319C08'
+gradient_color_2 = '#29CE10'
+gradient_color_3 = '#BDDE29'
+gradient_color_4 = '#DEA518'
+gradient_color_5 = '#D66600'
+gradient_color_6 = '#CE2910'
+
+[smoothing]
+noise_reduction = 10
+*/
+
+in vec2 fragCoord;
+out vec4 fragColor;
+
+// bar values. defaults to left channels first (low to high), then right (high to low).
+uniform float bars[512];
+
+uniform int bars_count;    // number of bars (left + right) (configurable)
+uniform int bar_width;    // bar width (configurable), not used here
+uniform int bar_spacing;    // space bewteen bars (configurable)
+
+uniform vec3 u_resolution; // window resolution
+
+//colors, configurable in cava config file (r,g,b) (0.0 - 1.0)
+uniform vec3 bg_color; // background color
+uniform vec3 fg_color; // foreground color
+
+uniform int gradient_count;
+uniform vec3 gradient_colors[8]; // gradient colors
+
+vec3 normalize_C(float y,vec3 col_1, vec3 col_2, float y_min, float y_max)
+{
+    //create color based on fraction of this color and next color
+    float yr = (y - y_min) / (y_max - y_min);
+    return col_1 * (1.0 - yr) + col_2 * yr;
+}
+
+void main()
+{
+    // find which bar to use based on where we are on the x axis
+    float x = u_resolution.x * fragCoord.x;
+    int bar = int(bars_count * fragCoord.x);
+
+    //calculate a bar size
+    float bar_size = u_resolution.x / bars_count;
+
+    //the y coordinate is stretched by 4X to resemble Winamp
+    float y =  min(bars[bar] * 4.0, 1.0);
+
+    // make sure there is a thin line at bottom
+    if (y * u_resolution.y < 1.0)
+    {
+      y = 1.0 / u_resolution.y;
+    }
+
+    vec4 bar_color;
+
+    if (gradient_count == 0)
+    {
+        bar_color = vec4(fg_color,1.0);
+    }
+    else
+    {
+        //find color in the configured gradient for the top of the bar
+        int color = int((gradient_count - 1) * y);
+
+        //find where on y this and next color is supposed to be
+        float y_min = float(color) / (gradient_count - 1.0);
+        float y_max = float(color + 1) / (gradient_count - 1.0);
+
+        //make a solid color for the entire bar
+        bar_color = vec4(normalize_C(y, gradient_colors[color], gradient_colors[color + 1], y_min, y_max), 1.0);
+    }
+
+
+    //draw the bar up to current height
+    if (y > fragCoord.y)
+    {
+        //make some space between bars based on settings
+        if (x > (bar + 1) * (bar_size) - bar_spacing)
+        {
+            fragColor = vec4(bg_color,1.0);
+        }
+        else
+        {
+            fragColor = bar_color;
+        }
+    }
+    else
+    {
+        fragColor = vec4(bg_color,1.0);
+    }
+}